10.1 Parametric Equations

Interactive Notes for Lesson & More!

Reminder: Use Shift-Enter while the cursor is anywhere within the code you would like to evaluate.

Use the examples here to help you graph your own curves to experiment and help with homework.

Notes Introduction: Projectile Motion Example

Cartesian Form

Style[TraditionalForm[HoldForm[y==-x^2/72+x]],20,FontFamily->"Times"]

Plot[-x^2/72+x,{x,0,72},AspectRatio->Automatic]

Parametric Form

Style[TraditionalForm[Row[{HoldForm[x=24Sqrt[2]t],",     ",HoldForm[y=-16t^2+24Sqrt[2]t]}]],20,FontFamily->"Times"]

ParametricPlot[{24Sqrt[2]t,-16t^2+24Sqrt[2]t},{t,0,3/Sqrt[2]}]

Parametric Plot Example

ParametricPlot[{5Cos[3t],3Sin[2t]},{t,0,2Pi}]

Animated Parametric Plot Example

Module[{r,tmin,tmax},

r[t_]:={5Cos[3t],3Sin[2t]};
tmin=0;
tmax=2Pi;

Manipulate[
Column[{Row[{"t = ",tmaxmax}],
Show[
ParametricPlot[r[t],{t,tmin,tmax},PlotStyle->Lighter[Gray,0.3]],
ParametricPlot[r[t],{t,tmin,tmaxmax},PlotStyle->Red],
Graphics[{PointSize[0.03],Point[r[tmaxmax]]}],
ImageSize->400,PlotRange->All,AxesLabel->{"x","y"}]
}],
{{tmaxmax,tmin+0.00001,"t"},tmin+0.00001,tmax}]
]

Notes: Page 1 Examples

Use the down-arrow openers on the left to open each section.

(RowDefault[x=(t^2)-4, ,  , y=(t/2), ,   , -2≤t≤3])

Manipulate[
Row[{
Style[Column[{
TraditionalForm[Row[{HoldForm[x=t^2-4],", ",HoldForm[y=t/2],"      "}]],
Row[{"t = ",Round[tmaxmax,0.001]}],
Row[{TraditionalForm[HoldForm[-2≤t≤3]]}]
}],16],
Show[
ParametricPlot[{t^2-4,t/2},{t,-2,3},PlotStyle->Lighter[Gray,0.3]],
ParametricPlot[{t^2-4,t/2},{t,-2+0.000001,tmaxmax-0.000001},PlotStyle->Red],
Graphics[{PointSize[0.03],Point[{t^2-4,t/2}/.t->tmaxmax]}],
ImageSize->300,PlotRange->{{-6,6},{-2,2}},AspectRatio->Automatic,ImagePadding->10]
}],
{{tmaxmax,-2,"t"},-2,3,ImageSize->Large},
{{tmaxmax,-2,"t"},-2,3,Trigger}
]

({{(RowDefault[x=4 (t^2)-4, , , y=t, ,  , -1≤t≤(3/2)])}})

Manipulate[
Row[{
Style[Column[{
TraditionalForm[Row[{HoldForm[x=4t^2-4],", ",HoldForm[y=t],"    "}]],
Row[{"t = ",Round[tmaxmax,0.001]}],
Row[{TraditionalForm[HoldForm[-1≤t≤3/2]]}]
}],16],
Show[
ParametricPlot[{4t^2-4,t},{t,-1,3/2},PlotStyle->Lighter[Gray,0.3]],
If[-1≤tmaxmax≤3/2,{
ParametricPlot[{4t^2-4,t},{t,-1+0.000001,tmaxmax-0.000001},PlotStyle->Red],
Graphics[{PointSize[0.03],Point[{4t^2-4,t}/.t->tmaxmax]}]
},{}],
ImageSize->300,PlotRange->{{-6,6},{-2,2}},AspectRatio->Automatic,ImagePadding->10]
}],
{{tmaxmax,-2,"t"},-2,3,ImageSize->Large},
{{tmaxmax,-2,"t"},-2,3,Trigger}
]

({{(RowDefault[x=4 (t^2)-8 t, , , y=1-t, , , -(1/2)≤t≤2])}})

Manipulate[
Row[{
Style[Column[{
TraditionalForm[Row[{HoldForm[x=4t^2-8t],", ",HoldForm[y=1-t]}]],
Row[{"t = ",Round[tmaxmax,0.001]}],
Row[{TraditionalForm[HoldForm[-1/2≤t≤2]]}]
}],16],
Show[
ParametricPlot[{4t^2-8t,1-t},{t,-1/2,2},PlotStyle->Lighter[Gray,0.3]],
If[-1/2≤tmaxmax≤2,{
ParametricPlot[{4t^2-8t,1-t},{t,-1/2+0.000001,tmaxmax-0.000001},PlotStyle->Red],
Graphics[{PointSize[0.03],Point[{4t^2-8t,1-t}/.t->tmaxmax]}]
},{}],
ImageSize->300,PlotRange->{{-6,6},{-2,2}},AspectRatio->Automatic,ImagePadding->10]
}],
{{tmaxmax,-2,"t"},-2,3,ImageSize->Large},
{{tmaxmax,-2,"t"},-2,3,Trigger}
]

All Together

Manipulate[
Row[{

Row[{
Column[{
TraditionalForm[Row[{HoldForm[x=t^2-4],", ",HoldForm[y=t/2],"      "}]],
Row[{"t = ",Round[tmaxmax,0.001]}],
Row[{TraditionalForm[HoldForm[-2≤t≤3]]}]
}],
Show[
ParametricPlot[{t^2-4,t/2},{t,-2,3},PlotStyle->Lighter[Gray,0.3]],
ParametricPlot[{t^2-4,t/2},{t,-2+0.000001,tmaxmax-0.000001},PlotStyle->Red],
Graphics[{PointSize[0.03],Point[{t^2-4,t/2}/.t->tmaxmax]}],
ImageSize->300,PlotRange->{{-6,6},{-2,2}},AspectRatio->Automatic,ImagePadding->10]
}],

Row[{
Column[{
TraditionalForm[Row[{HoldForm[x=4t^2-4],", ",HoldForm[y=t],"    "}]],
Row[{"t = ",Round[tmaxmax,0.001]}],
Row[{TraditionalForm[HoldForm[-1≤t≤3/2]]}]
}],
Show[
ParametricPlot[{4t^2-4,t},{t,-1,3/2},PlotStyle->Lighter[Gray,0.3]],
If[-1≤tmaxmax≤3/2,{
ParametricPlot[{4t^2-4,t},{t,-1+0.000001,tmaxmax-0.000001},PlotStyle->Red],
Graphics[{PointSize[0.03],Point[{4t^2-4,t}/.t->tmaxmax]}]
},{}],
ImageSize->300,PlotRange->{{-6,6},{-2,2}},AspectRatio->Automatic,ImagePadding->10]
}],

Row[{
Column[{
TraditionalForm[Row[{HoldForm[x=4t^2-8t],", ",HoldForm[y=1-t]}]],
Row[{"t = ",Round[tmaxmax,0.001]}],
Row[{TraditionalForm[HoldForm[-1/2≤t≤2]]}]
}],
Show[
ParametricPlot[{4t^2-8t,1-t},{t,-1/2,2},PlotStyle->Lighter[Gray,0.3]],
If[-1/2≤tmaxmax≤2,{
ParametricPlot[{4t^2-8t,1-t},{t,-1/2+0.000001,tmaxmax-0.000001},PlotStyle->Red],
Graphics[{PointSize[0.03],Point[{4t^2-8t,1-t}/.t->tmaxmax]}]
},{}],
ImageSize->300,PlotRange->{{-6,6},{-2,2}},AspectRatio->Automatic,ImagePadding->10]
}]

}],
{{tmaxmax,-2,"t"},-2,3,ImageSize->Large},
{{tmaxmax,-2,"t"},-2,3,Trigger}
]

Notes: Page 2 Examples

Try graphing your own

ParametricPlot[{(Subscript[f, x]),(Subscript[f, y])},{u,(Subscript[u, min]),(Subscript[u, max])}]

Trigonometric Example

ParametricPlot[{(Subscript[f, x]),(Subscript[f, y])},{t,0,2Pi}]

Animated

Module[{r,tmin,tmax},

r[t_]:={(Subscript[f, x]),(Subscript[f, y])};
tmin=0;
tmax=2Pi;

Manipulate[
Column[{Row[{"t = ",tmaxmax}],
Show[
ParametricPlot[r[t],{t,tmin,tmax},PlotStyle->Lighter[Gray,0.3],Exclusions->{Cos[t]==0},PlotPoints->ControlActive[20,20],MaxRecursion->ControlActive[3,3],ExclusionsStyle->If[showasymptotes,Directive@{Lighter[Blue,0.2],Dashing[Medium]},None]],
ParametricPlot[r[t],{t,tmin,tmaxmax},PlotStyle->Red,Exclusions->{Cos[t]==0}],
Graphics[{PointSize[0.03],Point[r[tmaxmax]]}],
ImageSize->400,PlotRange->10,AxesLabel->{"x","y"}]
}],
Row[{Control@{{tmaxmax,tmin+0.00001,"t"},tmin+0.00001,tmax},"     ",
Control@{{showasymptotes,True,"Asymptotes"},{True,False}}}]
]]

Exponential Example

Plot[3x E^(2x),{x,-4,1},PlotRange->{-1,3},AspectRatio->Automatic]

Different Parametrizations (Open Example: x = t, y=3t (e^(2t)))

Module[{r,tmin,tmax},

r[t_]:={t,3t E^(2t)};
tmin=-4;
tmax=1;

dsk[clr_,exp_]:=Row[{Graphics[{clr,Disk[]},ImageSize->15]," ",TraditionalForm[HoldForm[exp]],"  "}];

Manipulate[
Column[{
Row[{TraditionalForm[HoldForm[x=t]],",  ",TraditionalForm[HoldForm[y=3t E^(2t)]]}],
Row[{"t = ",tmaxmax}],
Show[
ParametricPlot[r[t],{t,tmin+0.00001,tmax-0.00001},PlotStyle->LightGray],
ParametricPlot[r[t],{t,tmin+0.00001,tmaxmax-0.00001},PlotStyle->Red],
If[MemberQ[showpt,1],#,{}]&@
Graphics[{PointSize[0.03],Point[r[tmaxmax]]}],
If[MemberQ[showpt,2],#,{}]&@
Graphics[{PointSize[0.03],Darker[Green],Point[r[tmaxmax^3]]}],
If[MemberQ[showpt,3],#,{}]&@
Graphics[{PointSize[0.03],Orange,Point[r[tmaxmax^2]]}],
If[MemberQ[showpt,4],#,{}]&@
Graphics[{PointSize[0.03],Darker[Yellow],Point[r[-tmaxmax^2]]}],
If[MemberQ[showpt,5],#,{}]&@
Graphics[{PointSize[0.03],Purple,Point[r[tmaxmax+1]]}],
If[MemberQ[showpt,6],#,{}]&@
Graphics[{PointSize[0.03],Brown,Point[r[tmaxmax-1]]}],
ImageSize->400,PlotRange->{{-4,1},{-1,3}},AspectRatio->Automatic,ImagePadding->10]
}],
{{tmaxmax,tmin,"t"},tmin,tmax,ImageSize->Large},
{{tmaxmax,tmin,"t"},tmin,tmax,Trigger},
{{showpt,{1},""},{1->dsk[Black,t],2->dsk[Darker[Green],t^3],3->dsk[Orange,t^2],4->dsk[Darker[Yellow],-t^2],5->dsk[Purple,t+1],6->dsk[Brown,t-1]},CheckboxBar}
]
]

Comparing Parametrizations

This is a separate notebook file. Or you can access it through the Wolfram Demonstrations website linked below.

https://demonstrations.wolfram.com/ComparingParametrizations/

Circles and Ellipses

ParametricPlot[{t,Sqrt[9-t^2]},{t,-3,3}]

ParametricPlot[{3Cos[t],3Sin[t]},{t,0,2Pi}]

ParametricPlot[{2Cos[t]+3,5Sin[t]-2},{t,0,2Pi}]

ParametricPlot[{2Sin[t]+3,5Cos[t]-2},{t,0,2Pi}]

Animation Illustrating Switching Sin and Cos

Module[{r,r2,tmin,tmax},

r[t_]:={Cos[t],Sin[t]};
r2[t_]:={Sin[t],Cos[t]};
tmin=0;
tmax=2Pi;

Manipulate[
Column[{Item[Row[{"t = ",tmaxmax}],ItemSize->{Automatic,3.5},Alignment->Center],
Row[{
Column[{Row[{"x = ",r[t][[1]]}],Row[{"y = ",r[t][[2]]}],
Show[
ParametricPlot[r[t],{t,tmin-0.00001,tmax},PlotStyle->Lighter[Gray,0.3]],
ParametricPlot[r[t],{t,tmin-0.00001,tmaxmax},PlotStyle->Red],
Graphics[{PointSize[0.03],Point[r[tmaxmax]]}],
ImageSize->200,PlotRange->All,AxesLabel->{"x","y"}]
},Alignment->Center],"   ",
Column[{Row[{"x = ",r2[t][[1]]}],Row[{"y = ",r2[t][[2]]}],
Show[
ParametricPlot[r2[t],{t,tmin-0.00001,tmax},PlotStyle->Lighter[Gray,0.3]],
ParametricPlot[r2[t],{t,tmin-0.00001,tmaxmax},PlotStyle->Red],
Graphics[{PointSize[0.03],Point[r2[tmaxmax]]}],
ImageSize->200,PlotRange->All,AxesLabel->{"x","y"}]
},Alignment->Center]
}]
}],
{{tmaxmax,tmin,"t"},tmin,tmax,Pi/12,ImageSize->Large}]
]

Manipulate for Ellipses

Manipulate[
ParametricPlot[{a Cos[t]+h,b Sin[t]+k},{t,0,2Pi},PlotRange->6],
{{a,1},0,5},{{b,2},0,5},{{h,3},-5,5},{{k,4},-5,5}]

Manipulate for Hyperbolas (basic)

Manipulate[
ParametricPlot[{a Sec[t]+h,b Tan[t]+k},{t,0,2Pi},PlotRange->6,Exclusions->{Cos[t]==0},ExclusionsStyle->Directive[{Orange,Thin}]],
{{a,2},0,5},{{b,2},0,5},{{h,-1},-5,5},{{k,2},-5,5}]

Manipulate for Hyperbolas (more features)

Module[{r},
Manipulate[
r[t_]:=If[switch,{a Tan[t]+h,b Sec[t]+k},{a Sec[t]+h,b Tan[t]+k}];
Column[{
Row[{"x = ",TraditionalForm[r[t][[1]]],",  y = ",TraditionalForm[r[t][[2]]]}],
ParametricPlot[r[t],{t,0,2Pi},PlotRange->6,ImageSize->400,Exclusions->{Cos[t]==0},ExclusionsStyle->Directive[{Orange,Thin}],AxesLabel->{"x","y"},Epilog->{If[showbox,{Opacity[0],EdgeForm[{Darker[Green,0.3],Dashed}],Rectangle[{h-a,k-b},{h+a,k+b}]},{}]}]
}],
{{a,2},0,5,Appearance->"Labeled"},{{b,2},0,5,Appearance->"Labeled"},
{{h,-1},-5,5,Appearance->"Labeled"},{{k,2},-5,5,Appearance->"Labeled"},
Row[{Control@{{switch,False,"switch sec & tan"},{True,False}},"      ",
Control@{{showbox,False,"show box"},{True,False}}}],
TrackedSymbols:>{a,b,h,k,switch,showbox}
]]

Hyperbola with Separate Graphs of Parametric Equations

Manipulate[
Module[{r,r1,r2},

r[t_]:=If[switchxy,{4Tan[t],3Sec[t]},{3Sec[t],4Tan[t]}];

r1[t_]:=r[t][[1]];r2[t_]:=r[t][[2]];

Row[{
Column[{
Show[
ParametricPlot[{t,r1[t]},{t,tmin,tmax},PlotStyle->Lighter[Gray,0.3],PlotPoints->ControlActive[20,20],MaxRecursion->ControlActive[3,3],Exclusions->{Cos[t]==0},ExclusionsStyle->If[showasymptotes,Directive@{Lighter[Blue,0.2],Dashing[Medium]},None]
],
ParametricPlot[{t,r1[t]},{t,tmin,tmaxmax},PlotStyle->Darker[Green,0.5],Exclusions->{Cos[t]==0},
ExclusionsStyle->None],
Graphics[{
If[showdistances,{Darker[Green,0.5],Line[{{tmaxmax,0},{tmaxmax,r1[tmaxmax]}}]},{}],
{PointSize[0.025],Point[{tmaxmax,r1[tmaxmax]}]},
{Text[Style[TraditionalForm[x==r1[t]],13,Black],{Pi,9}]}
}],
ImageSize->270,AspectRatio->0.6,PlotRange->{{0,2Pi},{-10,10}},AxesLabel->sty/@{"t","x"},Ticks->{Range[0,2Pi,Pi/2],Automatic},ImagePadding->{{0,12},{0,18}}],"",

Show[
ParametricPlot[{t,r2[t]},{t,tmin,tmax},PlotStyle->Lighter[Gray,0.3],PlotPoints->ControlActive[20,20],MaxRecursion->ControlActive[3,3],Exclusions->{Cos[t]==0},ExclusionsStyle->If[showasymptotes,Directive@{Lighter[Blue,0.2],Dashing[Medium]},None]
],
ParametricPlot[{t,r2[t]},{t,tmin,tmaxmax},PlotStyle->Purple,Exclusions->{Cos[t]==0},
ExclusionsStyle->None],
Graphics[{
If[showdistances,{Purple,Line[{{tmaxmax,0},{tmaxmax,r2[tmaxmax]}}]},{}],
{PointSize[0.025],Point[{tmaxmax,r2[tmaxmax]}]},
{Text[Style[TraditionalForm[y==r2[t]],13,Black],{Pi,9}]}
}],
ImageSize->270,AspectRatio->0.6,PlotRange->{{0,2Pi},{-10,10}},AxesLabel->sty/@{"t","y"},Ticks->{Range[0,2Pi,Pi/2],Automatic},ImagePadding->{{0,12},{0,18}}]
}],

Show[
ParametricPlot[r[t],{t,tmin,tmax},PlotStyle->Lighter[Gray,0.3],Exclusions->{Cos[t]==0},PlotPoints->ControlActive[20,20],MaxRecursion->ControlActive[3,3],ExclusionsStyle->If[showasymptotes,Directive@{Lighter[Blue,0.2],Dashing[Medium]},None]],
ParametricPlot[r[t],{t,tmin,tmaxmax},PlotStyle->Red,Exclusions->{Cos[t]==0}],
Graphics[{
If[showdistances,
{{Darker[Green,0.5],Line[{{0,r2[tmaxmax]},{r1[tmaxmax],r2[tmaxmax]}}]},
{Purple,Line[{{r1[tmaxmax],0},{r1[tmaxmax],r2[tmaxmax]}}]}},{}],
{PointSize[0.025],Point[r[tmaxmax]]}
}],
ImageSize->320,PlotRange->10,AxesLabel->sty/@{"x","y"}]
}]
],

Control@{{tmaxmax,tmin+0.00001,Style["t", Italic]},tmin+0.00001,tmax,Appearance->"Labeled"},"",
Row[{Control@{{showasymptotes,False,"asymptotes"},{True,False}},Spacer[20],
Control@{{showdistances,False,"distances"},{True,False}},Spacer[20],
Control@{{switchxy,False,Row[{"switch ",Style["x", Italic]," and ",Style["y", Italic]}]},{True,False}}
}],

Initialization:>{
tmin=0;tmax=2Pi;
sty[txt_]:=Style[txt,Italic,14,Black];}
]

More Examples

ParametricPlot[{3Sin[2t]Cos[3t],5Cos[3t]Sin[5t]},{t,0,2Pi}]

ParametricPlot[{3Sin[t]Cos[3t],5Cos[2t]Sin[3t]},{t,0,2Pi}]

ParametricPlot[{t^3 Cos[2t],t^3 Cos[1.5t]} ,{t,-2Pi,2Pi}]

Manipulate[
ParametricPlot[{t^3 Cos[a t],t^3 Cos[b t]},{t,-2Pi,2Pi},PlotRange->200],
{{a,2},1,10},
{{b,1.5},1,10}
]

3D: We do this in Calculus D

ParametricPlot3D[{3t^2/20,Cos[5t],t},{t,0,2Pi}]

ParametricPlot3D[{Cos[t],Sin[t],t/5},{t,0,6Pi}]

Additional Files

You may access these Demonstrations that I published on the Wolfram Demonstrations website. Click the “Download to Desktop” on the corresponding web page to download and interact with the files directly.

Parametric Curves in 2D
https://demonstrations.wolfram.com/ParametricCurvesIn2D/

Parametric Curves in 3D
https://demonstrations.wolfram.com/ParametricCurvesIn3D/

Comparing Parametrizations
https://demonstrations.wolfram.com/ComparingParametrizations/

Abby Brown - Torrey Pines High School - www.abbymath.com - Updated November 2015, 2020